need some help on this one

[Mustang01]

ok heres the deal, I have two civilian mustangs that i like to fly and 2 military mustangs...however, when it comes to engine hours ect, only 1 is logged, in other words, on the civilian mustang, i fly mustang 1, and i fly an hour, then fly mustang 2, for an hour, they both now have 2 hours, but the military mustang isnt changed. So my question is, how can i have each mustang in my hanger to have her own engine hours instead of putting hours on both even when the other hasn't been flown?

[BrettT]

I believe the aircraft are set up such that each type of aircraft has its own DAT file but not each livery. So to give a simpler example the J-3 cub standard and the j-3 cub with skis each have a separate file but the two j-3 cub standard liveries share the same DAT file. Since the civilian model is the same model throughout all three paint schemes they share the same DAT file but the military file is a different one from the civilian. I guess if you really wanted to, you could save the P51civlog.DAT file as something specific to the paint scheme that you are using then copy it back to P51civlog.dat when you want to use it....basically switch it out when you go for a flight

[Gypsy Baron]

ok heres the deal, I have two civilian mustangs that i like to fly and 2 military mustangs...however, when it comes to engine hours ect, only 1 is logged, in other words, on the civilian mustang, i fly mustang 1, and i fly an hour, then fly mustang 2, for an hour, they both now have 2 hours, but the military mustang isnt changed. So my question is, how can i have each mustang in my hanger to have her own engine hours instead of putting hours on both even when the other hasn't been flown?

All you need to do is create a folder for each aircraft, say P-51-1 and P-51-2.
Copy the current DAT file into each folder. If you want to start fresh, delete the DAT file and a new one will be
created when you load the aircraft. After the flight, save that DAT file in its folder.

Before loading one of the 2 aircraft, copy the 'saved' DAT file from its folder and overwrite the 'real' DAT file.
After the flight, copy the DAT file back to its save folder.

The DAT files for the Mil P51 are in 'My Documents\A2A\FSX\P51'. The current file name is: P51Log.dat
There are several BAK files that are the DAT files from the previous 5 flights.

I have actually created a BAT file to do that operation for my A2A aircraft that I want to keep separate hours on.
Here is the BAT file I use. You can change the folder names to those of your P51 variations. The file currently
only handles 2 different Mil P51 paints, Paint 1 and Paint 2 plus one 'other'.

Code: Select all

@echo off
REM This batch file will save or load one of three different A2A P51 Mil DAT files.
REM Place this batch file in your "\Documents\A2A\FSX\P51" and create a shortcut
REM to be placed on your desktop.

REM Sub-folders in the A2A\FSX\P51 folder and text files must be created first before
REM running the BAT file the first time.

REM Create a sub-folder for each P51 Mil paint you wish to save in the A2A\FSX\P51  folder.
REM This program, by default, uses:  Boomerang, JK Boomerang, and other.

REM NOTE: The text files should be of different sizes so,that the COMP command does
REM            not display each character  difference but only "Files are different sizes!"
REM            I just preceed the actual text with "." characters as needed to make the files different sizes. 
REM            Spaces added at the end will work as well. The file name must be "Loaded_Now.txt"

REM  A file named "f1.txt" and one named "Loaded_Now.txt" will be created in the 
REM  A2A\FSX\P51  folder the first time this file is run. These files are used
REM to prevent the current file from being saved in the wrong folder. 
REM The "OTHER"  option allows the current file to be unconditionally saved in the "Other" folder

REM This file has been tested on my Win7 Pro x64 system and works properly.
REM Use at your own risk. Backup your current DAT files as necessary. 
REM Created by Paul 'Gypsy Baron' Strogen - December 09, 2014

title Load or Save A2A P51 

REM  This file assumes that it is located in your "\My Documents\A2A\FSX\P51"
REM where the P51 DAT files are located.

@echo off
:start 
color 37
cls
echo This BAT file will Load or Save the A2A P51 DAT file

REM Save the current 'loaded now' text file for comparison later
type loaded_now.txt >f1.txt
echo .

REM Display the currently loaded dat file
type loaded_now.txt
echo .
echo .
echo Which P51 was/will be flown? 
echo 1.Boomerang
echo 2.JK Boomerang
echo 3.Another Paint  - Non-specific DAT file 
echo 4.Display the current file and Exit
 
:invalid_choice
set /p choice=enter your choice: 
if %choice%==1 goto Paint1
if %choice%==2 goto Paint2
if %choice%==3 goto OTHER
if %choice%==4 goto GoOut
echo invalid choice: %choice%
goto invalid_choice
 
REM Change the sub-folder names below ( cd N990CP, etc ) to match your setup

:Paint1
cd Boomerang
goto Direction

:Paint2
cd JK Boomerang
goto Direction

:OTHER
cd other

echo Load or Save the 'other' DAT file? 
echo 1.Load
echo 2.Save
color 17

set /p choice=enter your choice: 
if %choice%==1 goto Load_it
if %choice%==2 goto DoIt
echo invalid choice: %choice%

:DoIt
copy ..\P51Log.dat  /Y
copy loaded_now.txt .. /y
echo The current DAT file has been saved as the 'other' file!
goto GoOut

:Direction
echo Load or Save the DAT file? 
echo 1.Load
echo 2.Save

set /p choice=enter your choice: 
if %choice%==1 goto Load_it
if %choice%==2 goto Save_it
echo invalid choice: %choice%
goto Direction

:Load_it
color 27
@echo off
copy P51Log.dat .. /y
copy loaded_now.txt .. /y

REM Step back to the P51 directory
CD ..
echo The P51 file...
goto GoOut:

:Save_it
color 17
@echo off
echo N | comp ..\f1.txt  loaded_now.txt  /A  
IF NOT ERRORLEVEL 1 goto FileOK
color 47
echo DAT file mismatch! No file saved!
REM Step back to the P51 directory
CD ..
pause
goto start
exit

:FileOK
color 27
type ..\loaded_now.txt
echo and will be saved.
copy ..\P51Log.dat  /Y

REM Step back to the P51 directory
CD ..
echo The current P51 file was saved!

:GoOut
type loaded_now.txt
pause
exit

Here is the BAT file for the Civ P51.

Code: Select all

@echo off
REM This batch file will save or load one of three different A2A P51 Civ DAT files.
REM Place this batch file in your "\Documents\A2A\FSX\P51civ" and create a shortcut
REM to be placed on your desktop.

REM Sub-folders in the A2A\FSX\P51civ folde and text files must be created first before
REM running the BAT file the first time.

REM Create a sub-folder for each P51 Civ paint you wish to save in the A2A\FSX\P51civ  folder.
REM This program, by default, uses: Moombeam, Glamorous Gal, and N5412V.

REM NOTE: The text files should be of different sizes so,that the COMP command does
REM            not display each character  difference but only "Files are different sizes!"
REM            I just preceed the actual text with "." characters as needed to make the files different sizes. 
REM            Spaces added at the end will work as well. The file name must be "Loaded_Now.txt"

REM  A file named "f1.txt" and one named "Loaded_Now.txt" will be created in the 
REM  A2A\FSX\P51civ  folder the first time this file is run. These files are used
REM to prevent the current file from being saved in the wrong folder. 
REM The "OTHER"  option allows the current file to be unconditionally saved in the "Other" folder

REM This file has been tested on my Win7 Pro x64 system and works properly.
REM Use at your own risk. Backup your current DAT files as necessary. 
REM Created by Paul 'Gypsy Baron' Strogen - December 09, 2014

title Load or Save A2A P51civ 

REM  This file assumes that it is located in your "\My Documents\A2A\FSX\P51civ"
REM where the P51civ DAT files are located.

@echo off
:start 
color 37
cls
echo This BAT file will Load or Save the A2A P51 Civilian DAT file

REM Save the current 'loaded now' text file for comparison later
type loaded_now.txt >f1.txt
echo .

REM Display the currently loaded dat file
type loaded_now.txt
echo .
echo .
echo Which P51 was/will be flown? 
echo 1.Moonbeam McSwine
echo 2.Glamorous Gal
echo 3.N5412V
echo 4.Display the current file and Exit
 
:invalid_choice
set /p choice=enter your choice: 
if %choice%==1 goto Paint1
if %choice%==2 goto Paint2
if %choice%==3 goto Paint3
if %choice%==4 goto GoOut
echo invalid choice: %choice%
goto invalid_choice
 
REM Change the sub-folder names below ( cd N990CP, etc ) to match your setup

:Paint1
cd Moonbeam
goto Direction

:Paint2
cd Glamorous Gal
goto Direction

:Paint3
cd N5412V
goto Direction

:Direction
echo Load or Save the DAT file? 
echo 1.Load
echo 2.Save

set /p choice=enter your choice: 
if %choice%==1 goto Load_it
if %choice%==2 goto Save_it
echo invalid choice: %choice%
goto Direction

:Load_it
color 27
@echo off
copy P51civLog.dat .. /y
copy loaded_now.txt .. /y

REM Step back to the P51civ directory
CD ..
echo The P51civ file...
goto GoOut:

:Save_it
color 17
@echo off
echo N | comp ..\f1.txt  loaded_now.txt  /A  
IF NOT ERRORLEVEL 1 goto FileOK
color 47
echo DAT file mismatch! No file saved!
REM Step back to the P51civ directory
CD ..
pause
goto start
exit

:FileOK
color 27
type ..\loaded_now.txt
echo and will be saved.
copy ..\P51civLog.dat  /Y

REM Step back to the P51civ directory
CD ..
echo The current P51 Civilian file was saved!

:GoOut
type loaded_now.txt
pause
exit

Hope this helps.

Paul